home *** CD-ROM | disk | FTP | other *** search
/ Chip 1998 September / CHIP NET Rehberi Eylül 1998.iso / ftp / iftp21 / IHUB.ZIP / IHUB.BAT next >
DOS Batch File  |  1997-06-24  |  7KB  |  194 lines
  1. @echo off
  2. :====================================================================
  3. : IHUB.BAT  (c) copyright 1997 Santronics Software Inc
  4. :
  5. : NOTE: This batch file is designed for PX/WINS sysops.
  6. :
  7. : This batch file will handle complete IHub operations.  It does
  8. : complete FTN netmail, echos and TICS and Internet Email.
  9. : In addition, it will do PXFIDS, which offers a way to send FTN data
  10. : (netmail, echos and tics) to downlinks and uplinks.
  11. :
  12. : This batch file does the following:
  13. :
  14. : EXPORT:  Move files to be sent to the EXPORT directory.
  15. :
  16. : 1) If wcgate is defined, move all wcmail gateway mail to gexport
  17. :    directory.
  18. :
  19. : 2) Run PXNET to create *.PKT files for routed netmail to IHub.
  20. :    The *.PKT files are created in the export directory.
  21. :
  22. : 3) Move all echo bundles belonging to the IHub to the export
  23. :    directory.
  24. :
  25. : 4) if available, runs PXFIDS /EXPORT to scan PX data queues to
  26. :    create internet email messages to route to down links using
  27. :    PXFIDS.
  28. :
  29. : DIAL: Dial IHub, send/receive all files.
  30. :
  31. : 1) Use the new iFTP.EXE intelligent FTP script system to reliably
  32. :    sent and receive all files.
  33. :
  34. : IMPORT:  Move all new files into appropiate directories.
  35. :
  36. : 1) Make PXNET and ECHO QUEUE files as sent
  37. :
  38. : 2) Run PXFIDS to process any incoming FIDS Internet Email. PXFIDS
  39. :    will process what it needs, and leave the rest behind.
  40. :
  41. : 3) Unzip and move all remaining Internet email to
  42. :    the WCMAIL gateway directory.
  43. :
  44. : 4) Move all echo mail files to the inbound\echo directory.
  45. :
  46. : 5) Move all tic files to the inbound\tics directory.
  47. :
  48. : 6) Move all remaining files to the inbound directory.
  49. :
  50. : 7) Create semaphores to trigger PX/WINS PXECHO
  51. :
  52. :====================================================================
  53. :                      VARIABLES TO BE DEFINED
  54. :====================================================================
  55.  
  56. : bname       bundle name for your IHub. See BUNDNAME.EXE on CD
  57. : fido        fido address of IHub
  58. : export      local FidoNet export directory, make a directory called export
  59. : gexport     local Internet export directory, make a directory called gexport
  60. : import      local FidoNet import directory, make a directory called import
  61. : gimport     local Internet import directory, make a directory called gimport
  62. : wcgate      WC5 Gateway Host directory, ie. c:\wc5\gateway\ihub
  63.  
  64.  set bname=
  65.  set fido=1:396/1
  66.  set export=export
  67.  set gexport=gexport
  68.  set import=import
  69.  set gimport=gimport
  70.  set wcgate=c:\wc5\gateway\ihub
  71.  
  72. :====================================================================
  73. :                       START BATCH OPERATION
  74. :====================================================================
  75.  
  76. :--------------------------------------------------------------------
  77. : Check to make sure bname is defined.
  78. :--------------------------------------------------------------------
  79.  
  80.   if .%bname% == .. goto bnameerr
  81.  
  82. :--------------------------------------------------------------------
  83. : If using wcmail, then move outbound internet e-mail to gexport 
  84. : directory.
  85. :--------------------------------------------------------------------
  86.  
  87.   if .%wcgate%. == .. goto nowcout
  88.   if exist %wcgate%\*.cmd move %wcgate%\*.cmd %gexport%
  89.   if exist %wcgate%\*.xqt move %wcgate%\*.xqt %gexport%
  90.   if exist %wcgate%\*.dat move %wcgate%\*.dat %gexport%
  91. :nowcout
  92.  
  93. :--------------------------------------------------------------------
  94. : Check for PX exported fido mail, if any, move to the export
  95. : directory.
  96. :--------------------------------------------------------------------
  97.  
  98.   pxnet /SCAN /PACK %fido% /FILE %export%\%bname%.pkt
  99.   if exist outbound\%bname%.* move outbound\%bname%.* %export%
  100.  
  101. :--------------------------------------------------------------------
  102. : IF using FIDS, then check for any fids mail.
  103. :--------------------------------------------------------------------
  104.  
  105.   if exist pxfids.exe pxfids /EXPORT
  106.  
  107. :--------------------------------------------------------------------
  108. : Dial your provider and run iFTP script.
  109. :--------------------------------------------------------------------
  110.  
  111.   iftp /dial /run ihub
  112.   if errorlevel 1 goto raserror
  113.  
  114. :--------------------------------------------------------------------
  115. : Mark PX queues as sent.
  116. :--------------------------------------------------------------------
  117.  
  118.   pxnet /sent %fido%
  119.   viewout /sent %fido%
  120.  
  121. :--------------------------------------------------------------------
  122. : Check for any import FIDS mail.  FIDS will process any inbound
  123. : internet e-mail and delete the files in the import directory.
  124. :--------------------------------------------------------------------
  125.  
  126.   if exist pxfids.exe pxfids /IMPORT
  127.  
  128. :--------------------------------------------------------------------
  129. : If using wcgate, then check for imported internet e-mail.
  130. :--------------------------------------------------------------------
  131.  
  132.   if .%wcgate%. == .. goto nowcin
  133.   if exist %gimport%\*.d move %gimport%\*.d %wcgate%
  134.   if exist %gimport%\*.x move %gimport%\*.x %wcgate%
  135.   if exist %gimport%\*.zip pkunzip -o %gimport%\*.zip %wcgate%
  136.   if exist %gimport%\*.zip del %gimport%\*.zip
  137. :nowcin
  138.  
  139. :--------------------------------------------------------------------
  140. : See if there is any fidonet mail to do.
  141. :--------------------------------------------------------------------
  142.  
  143.   if not exist %import%\*.* goto end
  144.  
  145. :--------------------------------------------------------------------
  146. : Move bundles into inbound\echo directory.
  147. :--------------------------------------------------------------------
  148.  
  149.   if exist %import%\*.MO? move %import%\*.MO? inbound\echo
  150.   if exist %import%\*.TU? move %import%\*.TU? inbound\echo
  151.   if exist %import%\*.WE? move %import%\*.WE? inbound\echo
  152.   if exist %import%\*.TH? move %import%\*.TH? inbound\echo
  153.   if exist %import%\*.FR? move %import%\*.FR? inbound\echo
  154.   if exist %import%\*.SA? move %import%\*.SA? inbound\echo
  155.   if exist %import%\*.SU? move %import%\*.SU? inbound\echo
  156.  
  157. :--------------------------------------------------------------------
  158. : Move tics to inbound\tics directory.
  159. :--------------------------------------------------------------------
  160.  
  161.   if exist %import%\*.TIC move %import%\*.TIC inbound\tics
  162.  
  163. :--------------------------------------------------------------------
  164. : Move remaining files to inbound directory, px expects TIC files
  165. : to be in the normal inbound directory.
  166. :--------------------------------------------------------------------
  167.  
  168.   if exist %import%\*.* move %import%\*.* inbound
  169.  
  170.   echo >inbound\sema\$toss.0
  171.   echo >inbound\sema\$tics.0
  172.  
  173.   goto end
  174.  
  175. :-----------------------------------------------------------------------
  176. :bnameerr
  177.   echo Define the bname variable.  See bundname.exe
  178.  
  179. :-----------------------------------------------------------------------
  180. :raserror
  181.   ECHO FAILURE TO CONNECT
  182.   goto end
  183.  
  184. :-----------------------------------------------------------------------
  185. :end
  186.  set bname=
  187.  set fido=
  188.  set export=
  189.  set gexport=
  190.  set import=
  191.  set gimport=
  192.  set wcgate=
  193.  
  194.